IMPORT USER Command

You can use the Loader command IMPORT USER to import data that has been exported for a specific user. This imported data then belongs to the database user logged on to the database at the time of import.

Prerequisites

You have exported the required data using the corresponding EXPORT command.

Structure

Syntax Syntax

<import_user_command> ::=
  IMPORT USER
    [<duplicates_clause>]
    [<configuration_spec>]
    <catalog_data_instream_part_spec>
    [<package_spec>]
    [<restart_spec>]

<duplicates_clause> ::=
  REJECT DUPLICATES
| IGNORE DUPLICATES
| UPDATE DUPLICATES

<configuration_spec> ::=
  CONFIGURATION <instream_csv_spec>

<catalog_data_instream_part_spec> ::=
  <catalog_instream_spec>
| <data_instream_part_spec>
| <catalog_instream_spec> <data_instream_part_spec>
<catalog_instream_spec> ::=
  CATALOG <instream_ddl_spec>
<data_instream_part_spec> ::=
  DATA <instream_tableformat_spec>

<package_spec> ::=
  PACKAGE <oustream_csv_spec>

<restart_spec> ::=
  RESTART <package_guid>
<package_guid> ::=
  <unsigned_integer>

End of the code.

<catalog_instream_spec>, <data_instream_part_spec>

Depending on whether database catalog and/or application data is imported, the following data streams are generated during import:

Data stream for database catalog definitions CATALOG <instream_ddl_spec>
Data stream for application data DATA <instream_tableformat_spec>

Only one of the formats PAGES or RECORDS is possible for the data stream for the instream_tableformat_spec application data.

See: Data Stream, PAGES, RECORDS

Syntax Syntax

IMPORT USER
  [<duplicates_clause>]
  [<configuration_spec>]
  <catalog_instream_spec> <data_instream_part_spec>
  [<package_spec>]
  [<restart_spec>]

End of the code.

This IMPORT USER command imports the data that was exported for the specific user (database catalog and application data).

Syntax Syntax

IMPORT USER
  <catalog_instream_spec>
  [<package_spec>]
  [<restart_spec>]

End of the code.

This IMPORT USER command imports the user-specific database catalog information belonging to the application.

Syntax Syntax

IMPORT USER
  [<duplicates_clause>]
  [<configuration_spec>]
  <data_instream_part_spec>
  [<package_spec>]
  [<restart_spec>]

End of the code.

This IMPORT USER command imports the user-specific application data.

<duplicates_clause>

You use the DUPLICATES clause to specify how to proceed when importing data from a data stream if a row with the same key as the new row already exists in the table. This clause is not evaluated if the data is imported into the database in PAGES format.

`REJECT DUPLICATES`	The new line is rejected with an error message (default value).
`IGNORE DUPLICATES`	The new line is not inserted.
`UPDATE DUPLICATES`	The new line overwrites the existing line.

<configuration_spec>

You can exclude tables from the import.

If you do not specify a data stream using CONFIGURATION <instream_csv_spec>, all the application data is imported.
If you specify a data stream using CONFIGURATION <instream_csv_spec>, you can exclude the application data of selected tables from the import of the instream_tableformat_spec application data. The tables must be identified in the data stream by specifying their schema and table name. The information about which tables are not exported is stored in the system tables. One way of displaying this information is to display the system table SYSLOADER.TRANSFORMATIONMODEL. The tables excluded from the export of the application data have the value TRUE in the EXCLUDE column.

The database catalog entries CATALOG <instream_ddl_spec> of all tables are always imported, regardless of the restrictions set using CONFIGURATION <instream_csv_spec>.

<package_spec>

You can export system table SYSLOADER.TRANSFORMATIONMODEL.

If you specify a data stream using PACKAGE <outstream_csv_spec>, all entries in the SYSLOADER.TRANSFORMATIONMODEL table are exported to this data stream. We recommend you use this option to create a log of the export or import process.
If you do not specify a data stream using PACKAGE <outstream_csv_spec>, the system table SYSLOADER.TRANSFORMATIONMODEL is not exported.

See: Additional Log Functions (package_spec)

<restart_spec>

You can restart the export or import using the package_guid (ID created by Loader for every command at runtime. This integer is always 24 bytes long). The user can determine the package_guid of the corresponding export or import commands from the SYSLOADER.TRANSFORMATIONMODEL table or the log file. You can restart the command with the corresponding package_guid using the restart_spec syntax element.

See: Restarting

Result

The application data and/or database catalog are imported to the data_instream_part_spec and catalog_instream_spec data streams. If necessary, all entries in the SYSLOADER.TRANSFORMATIONMODEL table are exported to the package_spec data stream.

Errors: The import cannot be completed successfully. In this case, Loader logs the cause of the error in the log file. The values PACKAGEGUID and CLIENTNODE are also written to the log file. The PACKAGEGUID is required if you want to restart the export.

Example

Loader Tutorial, IMPORT USER

More Information

Importing: Loader Commands

EXPORT USER Command

Loader Log File

Loader System Tables